利用VBA为Excel添加更多的打印功能

大家知道，Word可以进行多种方式打印，如打印奇数页、打印偶数页、打印当前页等。而Excel的各种版本一直没有这些功能，从节约纸张、提高打印效率方面来看，这无疑是一个小小的遗憾。我们可以通过自定义功能区来，用VBA来编写一个加载宏，实现以下多种打印功能，点击此处打开源文件下载页面（需注册本站会员）。

    1.打印工作表的奇数页或偶数页。

    2.打印当前页，即当前选定单元格所在的页面。

    3.双面打印。一面打印完毕后，只需将全部打印纸取出，将出纸方向改为进纸方向重新放入打印机，再单击提示对话框的“确定”按钮，即可打印全部纸张的另一面。    

    具体操作步骤如下。

    一、新建加载宏文件

    由于使用了VBA，首先必需将Excel的宏安全性设置为“启用所有宏”。

    打开Excel 2007，新建一个Excel文件，将文件另存为“其它格式”，保存类型选“Excel加载宏（*.xlam)类型”，文件名为“双面打印.xlam”，并修改保存位置到桌面。加载宏类型的文件可以在Excel启动时自动加载，其功能对所有工作簿都起作用，而不是针对某一个工作簿。为便于以后操作，可以暂时将文件保存在桌面上，然后关闭Excel 2007。

    二、自定义功能区

    1.修改customUI.xml文件

    在桌面上新建一个文件夹，命名为“customUI”，然后在该文件夹中新建一个文本文件，将文件名改为“customUI.xml”，注意扩展名为“xml”，而不是“txt”。右击该文件，选“编辑”打开（或用记事本打开），输入下列内容：

 
   
        
   
         
         
         
            
         
       
         
                    
              
     
   
 

    然后单击菜单“文件→另存为”，在弹出的“另存为”对话框中，将“编码”由“ANSI”改为“Unicode”，如图二。单击“保存”按钮，在弹出的替换文件对话框中选择“是”保存文件。

      

     说明：上述代码中“”表示自定义的选项卡名称为“双面打印”，“”表示控件组的显示名称为“双面打印工具”，“

”行定义了一个按钮，名称为“打印奇数页”，按钮图标为Excel 2007内置图标“PrintAreaMenu”，图标大小为普通大小，单击按钮将调用VBA中的"OddPagePrint"过程。通过上述代码，我们定义了如图一所示的自定义功能区。因为上述代码中含有中文字符，所以必需将编码改为“Unicode”，如果只有英文字符，可以不改编码。

2.修改压缩包文件

    Office 2007新的文件格式采用了基于XML的文件格式，新的Office Open XML格式的核心使用一些XML的引用架构和一个ZIP容器，其实就是一个ZIP压缩包。所以我们可以用压缩软件（如WinRAR）打开它，然后通过添加、修改其中文件的方法实现自定义功能区的目的。上面的customUI文件夹必须放入其中才能起作用，另外还必须修改其中“_rels”文件夹中的“.res”文件进行关联，具体步骤如下：

    1.右击“双面打印.xlam”文件，依次选择“打开方式→选择程序”，在“打开方式 ”对话框中选择解压软件，如“WinRAR压缩文件管理器”。WinRAR软件将弹出窗口，显示压缩包内的文件夹和文件，如图三。

      

    2.将桌面上的customUI文件夹用鼠标左键拖到WinRAR窗口内，在弹出的“压缩文件名和参数”对话框中单击“确定”，如图四，customUI文件夹将被复制到压缩包内。

      

    3.双击打开压缩包内的“_rels”文件夹，将该文件夹内的“.res”文件用鼠标左键拖到桌面上，右击该文件，选“编辑”打开（或用记事本打开），在最后的“”前加上下列代码：

    4.保存该文件，再将其拖回到压缩包内，覆盖原来的“.res”文件。

    三、添加VBA代码

    双击打开“双面打印.xlam”文件，如果上述操作正确无误，Excel 2007功能区中将出现“双面打印”选项卡。单击该选项卡，可以看到各自定义按钮及其图标。按Alt+F11，打开VBA编辑器，选中“VBAProject ("双面打印.xlam"),单击菜单“插入”→“模块”，插入名称为“模块1”的模块，在其中输入VBA代码，为每个按钮提供运行代码：

Sub TwoSidePrint(control As IRibbonControl)  '双面打印
    On Error Resume Next
    Dim TotalPageNums As Integer, i As Integer, j As Integer
    TotalPageNums = ExecuteExcel4Macro("Get.Document(50)")
    If (TotalPageNums = 0) Then '如果为零，说明没有可打印内容，退出程序
    MsgBox "Microsoft Excel 未发现任何可以打印的内容", 0 + 48
      Exit Sub
    End If
    If TotalPageNums = 1 Then
        ActiveSheet.PrintOut
        If Err.Number = 1004 Then
            MsgBox "打印时发生错误，请检查打印机设置", 0 + 48 '提示用户发生打印错误
        End If
        Exit Sub
    End If
    For j = Int(TotalPageNums / 2) + 1 To 1 Step -1
    ActiveWindow.SelectedSheets.PrintOut From:=2 * j, To:=2 * j
    Next j
    MsgBox "第一面打印完毕后，请将打印出的纸张全部取出，" & vbCrLf & vbCrLf & "将出纸方向变为进纸方向放入纸槽中，" & vbCrLf & vbCrLf & "单击“确定”，打印另一面。", vbOKOnly, "打印另一面"
    For i = 1 To Int(TotalPageNums / 2) + 1
        ActiveWindow.SelectedSheets.PrintOut From:=2 * i - 1, To:=2 * i - 1
        If Err.Number = 1004 Then
            MsgBox "打印时发生错误，请检查打印机设置", 0 + 48 '提示用户发生打印错误
            Exit Sub
        End If
    Next i
    End Sub

Sub OddPagePrint(control As IRibbonControl)  '打印奇数页
    On Error Resume Next
    Dim TotalPageNums, i As Integer
    TotalPageNums = ExecuteExcel4Macro("Get.Document(50)")
    If (TotalPageNums = 0) Then '如果为零，说明没有可打印内容，退出程序
        MsgBox "Microsoft Excel 未发现任何可以打印的内容", 0 + 48
        Exit Sub
    End If
    For i = 1 To Int(TotalPageNums / 2) + 1
        ActiveWindow.SelectedSheets.PrintOut From:=2 * i - 1, To:=2 * i - 1
        If Err.Number = 1004 Then
            MsgBox "打印时发生错误，请检查打印机设置", 0 + 48 '提示用户发生打印错误
            Exit Sub
        End If
    Next i
End Sub
Sub EvenPagePrint(control As IRibbonControl)  '打印偶数页
    On Error Resume Next
    Dim TotalPageNums As Integer, i As Integer
    TotalPageNums = ExecuteExcel4Macro("Get.Document(50)")
    If TotalPageNums = 0 Then '如果为零，说明没有可打印内容，退出程序
        MsgBox "Microsoft Excel 未发现任何可以打印的内容", 0 + 48
        Exit Sub
    End If
    If TotalPageNums = 1 Then
        MsgBox ("只有第一页!!!")
        End
    End If
    For i = 1 To Int(TotalPageNums / 2) + 1
        ActiveWindow.SelectedSheets.PrintOut From:=2 * i, To:=2 * i
        If Err.Number = 1004 Then
            MsgBox "打印时发生错误，请检查打印机设置", 0 + 48 '提示用户发生打印错误
            Exit Sub
        End If
    Next i
End Sub
Sub CurrentPagePrint(control As IRibbonControl)
    On Error Resume Next
    Dim m As Integer, n As Integer
    Dim vPageBreaksCount As Integer, hPageBreaksCount As Integer
    Dim NumPage As Integer, TotalPages As Integer
    TotalPages = ExecuteExcel4Macro("Get.Document(50)")  '总的打印页数
    If TotalPages = 0 Then
       MsgBox "Microsoft Excel 未发现任何可以打印的内容", 0 + 48
       Exit Sub
    End If
    hPageBreaksCount = ActiveSheet.HPageBreaks.Count   '返回水平分页符个数
    vPageBreaksCount = ActiveSheet.VPageBreaks.Count   '返回垂直分页符个数
    For n = 1 To hPageBreaksCount  'n返回当前水平分页符的数量
        If ActiveSheet.HPageBreaks(n).Location.Row > ActiveCell.Row Then Exit For
    Next
    For m = 1 To vPageBreaksCount  'm返回当前垂直分页符的数量
       If ActiveSheet.VPageBreaks(m).Location.Column > ActiveCell.Column Then Exit For
    Next
    If ActiveSheet.PageSetup.Order = xlOverThenDown Then  '按页面设置中的打印顺序确定当前单元格所处的页数
        NumPage = (n - 1) * (vPageBreaksCount + 1) + m    '先行后列
    Else
        NumPage = (m - 1) * (hPageBreaksCount + 1) + n    '先列后行
    End If
   
    '判断选定的单元格是否在打印区域中
    If ActiveCell.Value = "" Then  '如果选定的单元格为空
        ActiveCell.Value = 1       '给活动单元格赋予临时数值
        If ExecuteExcel4Macro("Get.Document(50)") > TotalPages Or NumPage > TotalPages Then '如果总的打印页数增多或单元格所处页数大于打印页数
            ActiveCell.Value = ""
            MsgBox "选定的单元格不在打印范围以内！"
            Exit Sub
        Else
            ActiveCell.Value = ""
            ActiveSheet.PrintOut From:=NumPage, To:=NumPage, Copies:=1
            If Err.Number = 1004 Then
            MsgBox "打印时发生错误，请检查打印机设置", 0 + 48 '提示用户发生打印错误
            Exit Sub
        End If
            Exit Sub
        End If
    Else
        ActiveSheet.PrintOut From:=NumPage, To:=NumPage, Copies:=1
        If Err.Number = 1004 Then
            MsgBox "打印时发生错误，请检查打印机设置", 0 + 48 '提示用户发生打印错误
            Exit Sub
        End If
    End If
End Sub

    然后单击VBA编辑器的“保存”按钮保存工程。

    四、添加到Excel加载项中

    如果不是经常进行双面打印，可以在每次打印前打开“Excel2007双面打印工具.xlam”文件，然后进行双面打印即可。

    如果需要经常进行双面打印，可以让Excel每次运行时，都自动加载“Excel2007双面打印工具.xlam”文件，使自定义的选项卡总是出现在Excel 2007的功能区中。这必需把上述文件添加到Excel加载项中。步骤如下：

    1.单击“Office 按钮”，再单击“Excel 选项”。

    2.在“Excel选项”对话框中单击“加载项”。

    3.直接单击“转到”，弹出“加载项”窗口。

    4.单击“浏览”，查找并选择“Excel2007双面打印工具.xlam”文件，单击“确定”。